% env.mp --Programa MetaPost para generar
%          los gráficos PostScript para 
%          env.w


% macro para marcar y etiquetar ángulos

labsize = 8pt;
angle_radius=16pt;
a_size=3.6pt;

def label_angle(expr a, b, c, l)=
  begingroup
    save s,p;
    save hl, t, dm; pair dm;
    path p;
    p = unitvector(a-b){(a-b) rotated 90}..unitvector(c-b);

    %s = a_size/length(point 1 of p - point 0 of p);
    %if s<angle_radius : s:=angle_radius; fi
    s := angle_radius;

    p := p scaled s shifted b;
    drawarrow p;
    
    hl := .5*arclength p;
    t := arctime hl of p;
    dm := labsize*unitvector direction t of p rotated -90;
    label(l, dm shifted point t of p);
    %label.lft(l, p);
  endgroup
enddef;

% figura 1: envolvente convexa de un conjunto de puntos

beginfig(1);
  save u;
  u=3mm;
  z1 = (0u,4u);
  z2 = (4u,7u);
  z3 = (6u,4u);
  z4 = (5u,0u);
  z5 = (1u,1u);
  draw z1--z2--z3--z4--z5--cycle;
  pickup pencircle scaled 4pt;
  draw z1; draw z2; draw z3; draw z4; draw z5;
  draw (2u,5u); draw (3u,4u); draw (3u,1u); draw (4u,5u); draw (5u,3u);  
endfig;

% figura 2: ángulo de un vector

beginfig(2);
  save u;
  u = 5mm;
  z1 = (3u,2.5u);
  drawarrow (0,0)--z1;
  draw (x1,0)--z1 dashed evenly;
  draw (0,y1)--z1 dashed evenly;
  drawarrow (0,0)--(x1,0);
  drawarrow (0,0)--(0,y1);
  label.bot("x", (.5x1,0));
  label.lft("y", (0,.5y1));
  label_angle((x1,0),(0,0),z1,btex $\theta$ etex);
endfig;


% figura 3: ángulo entre dos vectores

beginfig(3);
  save u;
  u = 5mm;
  z1 = (3u,2.5u);
  z2 = (1u,4u);
  drawarrow (0,0)--z1;
  drawarrow (0,0)--z2;
  label.rt("(x1,y1)", z1);
  label.top("(x2,y2)", z2);
  label_angle(z1,(0,0),z2, btex $\theta$ etex);
endfig;

% figura 4: ángulo alpha

beginfig(4);
  save u;
  u = 3mm;
  pair zx;
  z1 = (3u,8u);
  z2 = (4u,3u);
  zx = 1.3[(0,0),z1];
  drawarrow (0,0)--z1;
  drawarrow (0,0)--z2;
  drawarrow z1--z2;
  draw z1--zx dashed evenly;
  label_angle(zx,z1,z2, btex $ \alpha $ etex);
  label.rt(btex $ p_i_j $ etex, z1);
  label.rt(btex $ p_i_{j+1} $ etex, z2);
  label.rt(btex $ p_i_{j+1}-p_i_j $ etex, 0.5[z1,z2])
endfig;


end