El PIC16F84A
DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.1

Índice / Introducción Familia PIC18 Registros del PIC16F84A

El PIC16F84A

Índice de contenidos


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.2

Características del PIC16F84A

    En esta parte estudiaremos la estructura del PIC16F84A con el fin de entender mejor su funcionamiento. Empezaremos con una relación de sus principales características:

    Para mantener la información sobre PIC actualizada es necesario obtener el archivo en PDF que se puede encontrar en www.microchip.com. También puede encontrarse como anexo 3 el archivo pic16f84a.pdf, en inglés.


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.3

Disposición y descripción de patillas

Disposición de patillas

    Disposición de patillas para encapsulado DIL 18:

Descripción de patillas

Nombre Tipo Descripción
OSC1/CLKIN 16 I Entrada del oscilador a cristal/Entrada de la fuente de reloj externa
OSC2/CLKOUT 15 O Salida del oscilador a cristal. En el modo RC, es una salida con una frecuencia de ¼ OSC1
MCLR 4 I/P Reset/Entrada del voltaje de programación.
RA0 17 I/O Puerto A bidireccional, bit 0
RA1 18 I/O Puerto A bidireccional, bit 1
RA21 I/O Puerto A bidireccional, bit 2
RA3 2 I/O Puerto A bidireccional, bit 3
RA4/T0CKI 3 I/O También se utiliza para la entra de reloj para el TMR0
RB0/INT 6 I/O Puerto B bidireccional, bit 0
Puede seleccionarse para entrada de interrupción externa
RB1 7 I/O Puerto B bidireccional, bit 1
RB2 8 I/O Puerto B bidireccional, bit 2
RB3 9 I/O Puerto B bidireccional, bit 3
RB4 10 I/O Puerto B bidireccional, bit 4
Interrupción por cambio de estado
RB5 11 I/O Puerto B bidireccional, bit 5
Interrupción por cambio de estado
RB6 12 I/OPuerto B bidireccional, bit 6
Interrupción por cambio de estado
RB7 13 I/O Puerto B bidireccional, bit 7
Interrupción por cambio de estado
Vss 5 P Tierra de referencia
Vdd 14 P Alimentación

DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.4

Arquitectura interna

    Las altas prestaciones de los microcontroladores PIC derivan de las características de su arquitectura. Están basados en una arquitectura tipo Harvard que posee buses y espacios de memoria por separado para el programa y los datos, lo que hace que sean más rápidos que los microcontroladores basados en la arquitectura tradicional de Von Neuman.

    Otra característica es su juego de instrucciones reducido (35 instrucciones) RISC, donde la mayoría se ejecutan en un solo ciclo de reloj excepto las instrucciones de salto que necesitan dos.

    Posee una ALU (Unidad Aritmético Lógica) de 8 bits capaz de realizar operaciones de desplazamientos, lógicas, sumas y restas. Posee un Registro de Trabajo (W) no direccionable que usa en operaciones con la ALU.

    Dependiendo de la instrucción ejecutada, la ALU puede afectar a los bits de Acarreo , Acarreo Digital (DC) y Cero (Z) del Registro de Estado (STATUS).

    La pila es de 8 niveles. No existe ninguna bandera que indique que esté llena, por lo que será el programador el que deberá controlar que no se produzca su desbordamiento.

    Este microcontrolador posee caracterísitcas especiales para reducir componentes externos con lo que se reducen los costos y se disminuyen los consumos. Posee 4 diferentes modos de oscilador, desde el simple circuito oscilador RC con lo que se disminuyen los costos hasta la utilización de un oscilador a cristal.

    En el modo SLEEP el consumo se reduce significativamente y puede ‘despertarse’ al microcontrolador utilizando tanto interrupciones internas como externas y señal de reset. Además posee la función Watchdog Timer (Perro Guardian) que protege al micro de ‘cuelgues’ debido a fallos software que produzcan bucles infinitos.


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.5

Memoria de programa

    La memoria de programa está organizada con palabras de 14 bits con un total de 1 K, del tipo Flash, que durante el funcionamiento es de solo lectura. Sólo se ejecutará el código contenido en esta memoria, pudiendo almacenar en ella una cantidad limitada de datos como parte de la instrucción RETLW. En una sola palabra se agrupa el código de la instrucción y el operando o su dirección.

    El tipo de memoria utilizada en este microcontrolador, podrá ser grabada o borrada eléctricamente a nuestro antojo desde el programador. La memoria tipo Flash tiene la característica de poderse borrar en bloques completos y no podrán borrarse posiciones concretas o específicas. Este tipo de memoria no es volátil, es decir, no pierde los datos si se interrumpe la energía.


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.6

    La memoria para almacenar el programa nos resultará perfecta para realizar pruebas y experimentos, además de para la programación "on-board" o "in-circuit", esto es, nos permite la programación del dispositivo o actualización del programa sin necesidad de retirarlo del circuito donde va montado.

    La memoria del programa comienza en la posición 0000h y termina en la posición 03FFh. Esto es 1Kbyte, es decir, 1024 bytes (210).

    En la figura también se muestra el PC (Contador de Programa o Program Counter). Que apunta a la dirección de memoria de la instrucción en curso y permite que el programa avance cuando se incrementa.

    También se muestra la pila o stack, de 8 niveles (Nivel Pila 1 a Nivel Pila 8). Se utiliza cuando ejecutamos un subproceso o subrutina, es decir, un conjunto de instrucciones que hemos aislado de las demás para simplificar. En este caso el contador de programa (PC) dejará de incrementarse y apuntará a la posición de memoria de programa donde empieza la subrutina; en el primer nivel de la pila se almacenará esta llamada, hasta que se acaben de ejecutar las instrucciones que contiene, momento en el cual se seguirá con las instrucciones desde donde había sido llamada. Por eso es necesario saber donde se quedó el programa almacenándose la dirección en la pila. Podemos hacer hasta 8 llamadas a subrutinas una dentro de otra, como si de muñecas rusas se tratase. A esto se le llaman subrutinas anidadas.

    El vector de reset se encuentra en la posición 0000h y el de interrupción en la 0004h.

    Debido a que el PIC16F84A tiene un contador de programa de 13 bit puede direccionar un espacio de memoria de 8K x 14, sin embargo sólo el primer 1K x 14 (0000h-03FFh) está implementado físicamente.

    Tener acceso a una localización por encima de la dirección físicamente implementada producirá un solapamiento. Por ejemplo, para las localizaciones 20h, 420h , 820h, C20h, 1020h, 1420h, 1820h, y 1C20h, la dirección real será la misma, así 20h es 32d y 420h es 1056d, 1056d menos 1024d es igual a 32d, es decir, se direcciona realmente la localización 20h, en binario 20h es 100000b y 420h es 10000100000b, 1K se direcciona con 10 bits (210 = 1024) de manera que de 10000100000b si sólo se tienen en cuenta 10 bits queda 0000100000b que es 20h. Con esto debe quedar claro que después de 3FF, al incrementarse el PC y pasar a 400, se direccionará de nuevo la posición 0h

    Existen varias versiones de memoria de programa para los PIC16f84A:

    Las memorias FLASH han sustituido a las EEPROM y son muy útiles al permitir que los microcontroladores que las incorporan puedan ser reprogramados "en circuito", es decir, sin tener que sacar el circuito integrado de la tarjeta. Así, un dispositivo con este tipo de memoria incorporado al control del motor de un automóvil permite que pueda modificarse el programa durante la rutina de mantenimiento periódico, compensando los desgastes y otros factores tales como la compresión, la instalación de nuevas piezas, etc. La reprogramación del microcontrolador puede convertirse en una labor rutinaria dentro de la puesta a punto.


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.7

Memoria de datos

    Está organizada en dos páginas o bancos de registro, banco 0 y banco 1. Para cambiar de página se utiliza un bit del registro STATUS (RP0).

    Cada banco se divide a su vez en dos áreas:

    En la figura siguiente nos podemos hacer una idea de cómo están distribuidos:


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.8

    La primera es la de RFS (Registros de Funciones Especiales) que controlan el funcionamiento del dispositivo. Estos se emplean para el control del funcionamiento de la CPU y de los periféricos.

    El segundo área (68 bytes SRAM) es la de RGP (Registros de Propósito General), y puede accederse a ellos tanto directa como indirectamente haciendo uso del registro FSR.

    Banco 0:

    Banco 1:

    La memoria RAM así como algunos registros especiales son los mismos en los dos bancos del mapa de memoria del PIC. La anchura de los bytes en la memoria es de 8 bis.

    Para direccionar la memoria de datos se emplean dos modos de direccionamiento, el directo y el indirecto. En el direccionamiento directo, los 7 bits de menos peso del código OP de la instrucción proporcionan la dirección en la posición de la página, mientras que los bits RP1 y RP0 de STATUS seleccionan la página o banco.

    En el direccionamiento indirecto el operando de la instrucción hace referencia al registro IDNF, que ocupa la posición 00h del área de datos. Se accede a la posición que apunta el registro FSR 04h del banco 0. Los 7 bits de menos peso de FSR seleccionan la posición y su bit de más peso, junto con el bit IRP del registro de estado, seleccionan la página.

    Para más información ver Registros del PIC16F84A.

El direccionamiento

    Para el PIC solamente existen 4 modos de direccionamiento, entre los cuales, tres de ellos ya fueron vistos de manera intuitiva cuando vimos las instrucciones. Los modos de direccionamiento tratan sobre la forma de mover los datos de unas posiciones de memoria a otras.

Direccionamiento Inmediato

    El dato manipulado por la instrucción se codifica con la propia instrucción. En este caso, el dato en cuestión se denomina literal.

	MOVLW k ; Coloca el literal k, que es un valor cualquiera codificado con 8 bits, en el registro de trabajo w

Direccionamiento Directo

    La memoria interna se direcciona de forma directa por medio de los 8 bits "f" contenidos en las instrucciones que operan sobre registros. De esta manera se puede direccionar cualquier posición desde la 00 a la FF.

    En los microcontroladores que tengan más de un banco, antes de acceder a alguna variable que se encuentre en la zona de los bancos de registros, el programador deberá asegurarse de haber programado los bits de selección de banco en el registro OPTION.

    Este es el modo más utilizado, ya que como hemos visto anteriormente, la memoria RAM está dividida en registros específicos y en un conjunto de registros de propósito general. Este modo consiste en codificar el nombre del o de los registros en cuestión directamente en la instrucción.

	MOVWF f ; Desplaza el contenido del registro w al registro f

Direccionamiento bit a bit

    Mediante este direccionamiento se manipula un bit individual en cualquier registro. Este modo de direccionamiento no se utiliza nunca solo, sino que siempre va emparejado con el modo de direccionamiento directo.

	BCF f,b ; Pone a cero el bit número b del registro f

Direccionamiento Indirecto

    Es el modo más potente y utiliza los registros INDF y FSR. En el registro FSR se introduce la dirección del registro que se quiere leer cuando se acceda a INDF.

    FSR actúa como puntero, es decir, el valor que guardemos en este registro será la dirección de una posición de memoria. Si aumentamos o disminuimos con cualquier operación el contenido de FSR nos moveremos entre las posiciones de memoria.


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.9

    El registro INDF no tiene existencia física, solamente está implementado en la posición 0 como modo de notación. La utilidad de este registro no es otra que acceder a los datos apuntados por el registro FSR, para poder modificarlos, etc.

    Esto se ve mucho más claro en los dos siguientes ejemplos. El primero de ellos es un pseudo-código para acceder a la RAM, y el segundo es un algoritmo para limpiarla.

Ejemplo 1:
  • El registro 05 contiene el valor 10 h.
  • El registro 06 contiene el valor 0A h.
  • Cargamos el valor 05 en el registro FSR.
  • Ahora está apuntado el registro 05.
  • Si leemos el registro INDF, este retornará el valor 10 h.
  • Incrementamos el registro FSR (FSR=FSR+1).
  • Ahora apunta a la posición 06.
  • Si leemos el registro INDF, este retornará el valor 0A h.
INDF10 h
001.
002.
003.
FSR05 h
00510 h
0060A h
007.
008.
009.
00A.
00B.
INDF0A h
001.
002.
003.
FSR06 h
00510 h
0060A h
007.
008.
009.
00A.
00B.

    Si leemos del registro INDF de manera indirecta (con FSR apuntándolo), el valor leído será 00. Si escribimos en este registro de manera indirecta, obtendremos una no-operación, aunque el registro estado se verá afectado.

Ejemplo 2:

    Limpiar la memoria RAM desde la posición 10 h a la 20 h.

		MOVLW		0X10	; Inicializamos puntero
		MOVWF		FSR	
NEXT		CLRF		INDF	; Limpiamos el registro apuntado
		INCF		FSR	; Incrementamos el puntero
		BTFSS		FSR,5	; ¿Los registros estan borrados?
		GOTO		NEXT	; No, limpiar siguiente
CONTINUAR				; Si, se continua con el programa

    Existe un quinto modo de direccionamiento llamado direccionamiento relativo que no trataremos por que no está implementado en los PICs.

Memoria de datos EEPROM

    Esta memoria está basada en tecnología EEPROM, y tiene una longitud de 8 bits, del mismo modo que la memoria de datos. Su tamaño es de 64 bytes y está situada en un bloque distinto y aislado de la de datos.

    Los 64 bytes EEPROM de Memoria de Datos no forman parte del espacio normal direccionable, y sólo es accesible en lectura y escritura a través de dos registros, para los datos el EEDATA que se encuentra en la posición 0008h del banco de registros RAM y para las direcciones el EEADR en la 0009h. Para definir el modo de funcionamiento de esta memoria se emplean dos registros especiales, el EECON1 en la dirección 0088h y el EECON2 en 0089h.

    Registros que se utilizan con la EEPROM:

    Esta memoria no emplea ningún recurso externo de alimentación. Puede grabarse desde un programador de PIC al igual que el código de programa.

    La lectura de una posición de la memoria se obtiene en el registro EEDATA en el próximo ciclo de reloj, si bien podría tardar algo mas.

    La escritura es mucho mas lenta, tardandose del orden de unos 8 ms. Esta se controla mediante un temporizador interno.

    Resumen de características:

    Cuando el dispositivo está protegido por código, la CPU puede continuar leyendo y escribiendo en la memoria EEPROM, pero el programador del dispositivo ya no puede acceder esta memoria.


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.10

Uso de la EEPROM

    A continuación veremos a fondo cuales son los procesos más usuales de escritura y de lectura en la EEPROM.

Lectura de la memoria EEPROM

    Para leer de la memoria EEPROM han de seguirse los siguientes pasos:

    Veamos dos ejemplos práctico. El primero (LECTURA1) presupone que el dato en EEDATA estará disponible rápidamente, y el segundo (LECTURA2) espera hasta confirmarlo:

LECTURA1	BCF	STATUS,RP0	; Selecciona banco 0
		MOVLW	MEM1		; Dirección a leer de
		MOVWF	EEADR		; la EEPROM
		BSF	STATUS,RP0	; Selecciona banco 1
		BSF	EECON1,RD	; Activar lectura
		BCF	STATUS,RP0	; Selecciona banco 0
		MOVF	EEDATA,W	; W se carga con el valor
					; leído en eeprom


LECTURA2	BCF	STATUS,RP0	; Selecciona banco 0
		MOVLW	MEM1		; Dirección a leer de
		MOVWF	EEADR		; la EEPROM
		BSF	STATUS,RP0	; Selecciona banco 1
		BSF	EECON1,RD	; Activar lectura
ESPERA		BTFSC	EECON1,RD	; Espera final de lectura
		GOTO	ESPERA		; a que baje la bandera
		BCF	STATUS,RP0	; Selecciona banco 0
		MOVF	EEDATA,W	; W se carga con el valor
					; leído en eeprom

    La memoria EEPROM es bastante lenta, por lo cual es importante esperar a que el ciclo de lectura termine, aunque algunas veces se omita. Pero es aún más importante esta espera en el ciclo de escritura, ya que la EEPROM puede tardar en ser escrita hasta 10 ms.

Escritura de la memoria EEPROM

    El proceso de escritura es aún más complejo ya que deberemos hacer todo lo anterior y además escribir un código especial de protección. Estos pasos los vemos en las siguientes líneas:


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.11

    Veamos un ejemplo de escritura típico que no utiliza interrupciones:

ESCRITURA	; Establecer EEADR y EEDATA
		MOVLW	DIRMEN1
		MOVWF	EEADR		; Escribe la dirección en EEADR
		MOVLW	DATO1
		MOVWF	EEDATA		; Se escribe el dato en EEDATA 
		BSF	STATUS,RP0	; Selecciona el banco 1
		BSF	EECON1,WREN	; Permiso de escritura activado
		;Comienzo de la secuencia de escritura
		MOVLW	0x55
		MOVWF	EECON2		; Se escribe el dato 55 h en EECON2
		MOVLW	0xAA
		MOVWF	EECON2		; Se escribe AA h en EECON2
		BSF	EECON1,WR	; Comienza la escritura
		BCF	EECON1,WREN	; Permiso de escritura desactivado
ESPERA		BTFSC	EECON1,WR	; Espera a que termine la escritura
		GOTO	ESPERA
		BCF	STATUS,R0 	; Selecciona el banco 0

    La escritura de cada byte no se iniciará si la secuencia de introducir 55 y AA en EECON2, y activar el bit WR no se sigue exactamente.

    Considerándo lo anterior, es recomendable que durante la secuencia de inicio de escritura se deshabiliten las interrupciones, con el fin de evitar errores no deseados y habilitarlas posteriormente si van a ser utilizadas.

    Adicionalmente, el bit WREN de EECON1 debe ser activado para habilitar la escritura. Para evitar errores, también es recomendable que el bit WREN esté desactivado durante todo el programa excepto en el momento de la escritura. Debemos tener en cuenta que este bit no se pone a cero automáticamente mediante hardware. Una vez iniciado el ciclo de escritura, si ponemos a cero WREN, esto no afectará a el ciclo de escritura iniciado. En este caso el bit WR estará inhibido y no se podrá poner a uno.

    Después del ciclo, el bit WR es puesto a cero por hardware y el EEIF es puesto a uno (si EEIE lo está). Si EEIE, está habilitado, EEIF debe ser puesto a cero por software.

    Veamos un ejemplo de escritura típico que utiliza interrupciones:

ESCRITURA	BCF	STATUS,RP0	; Selecciona el banco 0
		; Establecer EEADR y EEDATA
		MOVLW	MEN1
		MOVWF	EEADR		; Escribe la dirección en EEADR
		MOVLW	DATO1
		MOVWF	EEDATA		; Se escribe el dato en EEDATA 
		BSF	STATUS,RP0	; Selecciona el banco 1
		BSF	EECON1,WREN	; Permiso de escritura activado
		BCF	INTCON, GIE	; Desabilita interrupciones.
		;Comienzo de la secuencia de escritura
		MOVLW	0x55
		MOVWF	EECON2		; Se escribe el dato 55 h en EECON2
		MOVLW	0xAA
		MOVWF	EECON2		; Se escribe AA h en EECON2
		BSF	EECON1,WR	; Comienza la escritura
		BSF INTCON,GIE		; Habilita las interrupciones.
		BCF	EECON1,WREN	; Permiso de escritura desactivado
		BCF	STATUS,R0 	; Selecciona el banco 0

Verificación de la escritura

    Dependiendo de la aplicación, la experiencia en programación dice que los datos escritos en la EEPROM deben ser verificados comparándolos con el dato que se acaba de escribir. Esto debe usarse en aplicaciones en las que un bit de la EEPROM sufre ciclos de lectura/escritura hasta rozar el límite de las especificaciones. Generalmente el fallo de escritura en un bit de la EEPROM será un bit que se escribe como un 0 lógico pero devuelve un 1 debido a la pérdida de ese bit. La siguiente porción de código es un ejemplo de verificación del dato escrito:

		BCF	STATUS,RP0	; Nos situamos en el banco 0
		MOVF	EEDATA,W	; Debemos estar en el banco 0
		BSF	STATUS,RP0	; Cambiamos al banco 1
		BSF	EECON1,RD 	; Leemos el dato que se guarda en
		BCF	STATUS,RP0	; EEDATA, y cambiamos a banco 0
		; A continuación se comprueba que los datos en W en EEDATA son los mismos
		SUBWF	EEDATA,W	; Restamos ambos valores
		BTFSS	STATUS,Z	; Si la operación es cero, son iguales
		GOTO	ERR_ESCRIT	; Si no son iguales, saltamos a ERR_ESCRIT
		.....			; Si son iguales, seguimos con el programa

Rutinas EEPROM

    A continuación se presentan dos rutinas para escribir y leer en la EEPROM:

;**************************************************************
; EEPROM_W:
; Graba un byte en la EEPROM de datos. La dirección será la contenida
; en EEADR y el dato se le supone previamente introducido en EEDATA
;
EEPROM_W
	bsf	STATUS,RP0	;Selecciona banco 1
	bsf	EECON1,WREN	;Permiso de escritura
	movlw 	b'01010101'	;Secuencia de escritura
	movwf	EECON2
	movlw	b'10101010'
	movwf	EECON2	
	bsf	EECON1,WR	;Orden de escritura
	bcf	EECON1,WREN	;Desconecta permiso de escritura
ESPERA
	btfss	EECON1,EEIF	;Comprobar bandera de fin de escritura
	goto	ESPERA
	bcf	EECON1,EEIF	;Reponer flag de fin de escritura
	bcf	STATUS,RP0	;Selección banco 0
	return
;
;**************************************************************
; EEPROM_R:
; Lee un byte de la EEPROM. Se supone al registro EEADR cargado
; con la dirección a leer. En EEDATA aparecerá el dato leído.
;
EEPROM_R
	bsf	STATUS,RP0	;Selección de banco 1
	bsf	EECON1,RD	;Orden de lectura
	bcf	STATUS,RP0	;Selección de banco 0
	return
;**************************************************************

Puertos de E/S

    El PIC16F84 dispone de dos puertos digitales de E/S paralelos de uso general denominados Puerto A y Puerto B.

Puerto A

    El puerto A dispone de 5 líneas de la RA0 a la RA4, en la que hay que distinguir la A4 o T0CKI (Timer 0 Clock Input) que está compartida con la entrada para el Timer 0 (TMR0) a través de un trigger Schmitt y que cuando se configura como salida es de drenador abierto, por lo que debe colocarse una resistencia de polarización.

Diagrama de bloques de RA3:RA0 Diagrama de bloques de RA4

Puerto B

    El puerto B dispone de 8 líneas de E/S que van desde la RB0 a la RB7 (la línea RB0 o INT es compartida con la entrada de interrupción externa). Además, las líneas RB4 a RB7 puede programarse una interrupción por cambio de estado de cualquiera de estas líneas.

Diagrama de bloques de RB7:RB4 Diagrama de bloques de RB3:RB0

DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.12

    Cuando se produce una interrupción por cambio de estado de cualquiera de las líneas RB4 a RB7, para lo cual las líneas deben estar además programadas como entradas (ver registro INTCON e Interrupciones) el valor de la patilla en modo entrada es comparado con el valor almacenado en la báscula durante la última lectura del Puerto B. Los cambios en las patillas se detectan realizando una operación OR para la generación de una interrupción por cambio de estado. Esta interrupción puede despertar "wake up" al microcontrolador del modo de reposo SLEEP. El usuario debe borrar la interrupción en la Rutina de Servicio de Interrupción RSI de una de las siguientes maneras:

    Una condición "mismacht" puede producir que el bit RBIF siga a "1". Leyendo el puerto B puede finalizar la condición de "mismacht" y permitiendo que el bit RBIF sea puesto a "0".

    Además, todas las líneas del Puerto B disponen de resistencias internas de polarización programables "pull-up" de alto valor. Cada una de las 8 resistencias pueden ser activadas o deshabilitadas haciendo uso del bit RBPU del registro especial OPTION. Estas resistencias se deshabilitan automáticamente si una línea es programada como salida así como durante el proceso de Power On Reset.

Configuración de los puertos de Entrada/Salida

    Cualquier línea puede funcionar como entrada o como salida. Sin embargo, si actúa como entrada la información que se introduce no se memoriza, por lo que la información debe ser mantenida hasta que sea leída. Si la línea actúa como salida, el bit que procede del bus de datos se guarda en la báscula, con lo que la información que ofrece esta patita permanece invariable hasta que se reescriba este bit.

    Los bits de cada puerto se configuran mediante los bits correspondientes de dos registros especiales de control :

    Los Puertos A y B (PORTA y PORTB) se corresponden con las posiciones 5 y 6 del área de datos.

    Cuando se produce un reset, todos los bits de los registros TRIS pasan a tener el valor 1 y todas las líneas de E/S actúan como entrada por evidentes motivos de seguridad para evitar daños irreparables. Todas las patillas de E/S que no se empleen deben ser llevadas a +5v, regla de las entradas CMOS, preferiblemente a través de una resistencia para evitar que si por error se configurasen como salidas puedan darse problemas si presentan un estado bajo.

    Para mas información, ver "Registro TRISA y TRISB (85h y 86h)" de "Registros del PIC16F84A" así como "Instrucciones y puertos" de "Técnicas de programación".


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.13

Limite de corriente para los puertos

    Los puertos del microcontrolador PIC16F84 son el medio de comunicación con el mundo exterior, en ellos podremos conectar los periféricos o circuitos necesarios como por ejemplo los módulos LCD, teclados matriciales, motores eléctricos, etc; pero estas conexiones no se podrán realizar arbitrariamente. Existen unas reglas básicas que deberán cumplirse para que el microcontrolador no sufra daños o se destruya. Para ello es necesario conocer los límites de corriente que puede manejar el microcontrolador.

    Como anteriormente hemos indicado los puertos A y B del microcontrolador podrán ser programados como entradas ó salidas indiferentemente. En el caso de que sean programados como salida y presenten un nivel lógico alto actuaran como "fuente" porque suministran corriente y cuando presenten un nivel lógico bajo actuarán como "sumidero" por que reciben corriente.

    De todas maneras hay que tener en cuenta no superar la disipación de potencia máxima, que se calcula como sigue:

        Pdis = VDD x (IDD - Σ IOH) + Σ {(VDD-VOH) x IOH} + Σ (VOL x IOL)

    VOH suele ser VDD-0,7 v y VOL 0,6 v.

    El consumo de corriente (IDD) es principalmente función de la tensión de alimentación y de la frecuencia. Otros factores, como cambios en E/S, tipo de oscilador, temperatura y otros tienen influencia en el consumo. La IDD para el PIC16F84A-4 está entre 1,8 a 4.5 mA en configuración de oscilador RC y XT (FOSC=4 MHz, VDD=5,5V), con las patillas como entradas y unidas a positivo.

    En caso de que se necesiten utilizar periféricos que manejen mayor cantidad de corriente de la especificada, habrá que aplicar un circuito adaptador como por ejemplo buffers o transistores.


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.14

    En la siguiente figura vemos una configuración típica en la que se utilizan buffers de corriente, que proporcionan en su salida el mismo nivel lógico que la entrada pero pueden controlar corrientes relativamente elevadas. En este caso se utiliza el ULN2803, un circuito integrado que consiste en 8 buffers de potencia capaces de suministrar en su salida hasta 1 A, mucho más de lo que es capaz de soportar un PIC:

Temporizador/Contador TMR0

    El temporizador/contador TMR0 es un registro de 8 bits, es decir, un particular tipo de registro cuyo contenido es incrementado con una cadencia regular y programable directamente por el hardware del PIC. Como es de 8 bits, el máximo de la cuenta está en 255.

    El TMR0 tiene las siguientes características:

    Este registro puede usarse para contar eventos externos por medio de un pin de entrada especial (modo contador) o para contar pulsos internos de reloj de frecuencia constante (modo temporizador). Además, en cualquiera de los dos modos, se puede insertar un prescaler, es decir un divisor de frecuencia programable que puede dividir por 2, 4, 8, 16, 32, 64, 128 o 256. Este divisor puede ser utilizado alternativamente como prescaler o del TMR0 o como postscaler del Watch Dog Timer, según se lo programe.

    En la práctica, a diferencia de los otros registros, el TMR0 no mantiene inalterado el valor que tiene memorizado, sino que lo incrementa continuamente.

    Si por ejemplo escribimos en él el valor 10, después de un tiempo igual a cuatro ciclos máquina, el contenido del registro comienza a ser incrementado a 11, 12, 13 y así sucesivamente con una cadencia constante y totalmente independiente de la ejecución del resto del programa.


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.15

    Una vez alcanzado el valor 255, el registro TMR0 es puesto a cero automáticamente comenzando entonces a contar desde cero y no desde el valor originalmente cargado.

    La frecuencia de conteo es directamente proporcional a la frecuencia de reloj aplicada al PIC y puede ser modificada programando adecuadamente algunos bits de configuración.

    El modo temporizador se selecciona colocando a 0 el bit T0CS del registro OPTION. En este modo, el Timer0 se incrementa con cada ciclo de instrucción (con el divisor desactivado).

    El modo contador se selecciona colocando a 1 el bit T0CS del registro OPTION. En este modo, el contador se incrementará con cada flanco de subida o de bajada del pin RA4/T0CKI. El flanco se selecciona con el bit T0SE del registro OPTION.

    Se generará una interrupción cuando el registro TMR0 se desborda de FFh a 00h. Este desbordamiento se indicará el el bit T0IF del registro INTCON.

    En la siguiente figura está representado el esquema de bloques internos del PIC que determinan el funcionamiento del registro TMR0:

    Fosc/4 y T0CKI representan las dos posibles fuentes de señal de reloj, para el contador TMR0.

    Fosc/4 es una señal generada internamente por el PIC tomada del circuito de reloj y que es igual a la frecuencia del oscilador dividida por cuatro.

    T0CKI es una señal generada por un posible circuito externo y aplicada al pin T0CKI correspondiente al pin 3 del PIC16F84.

    Los bloques T0CS y PSA son dos selectores de señal (multiplexores) en cuya salida se presenta una de las dos señales de entrada en función del valor de los bits T0CS y PSA del registro OPTION.

    El bloque PRESCALER ó Predivisor es un divisor programable cuyo función es dividir la frecuencia de conteo, interna ó externa.


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.16

El Prescaler

    El PRESCALER consiste en un divisor programable de 8 bits a utilizar en el caso de que la frecuencia de conteo enviada al contador TMR0 sea demasiado elevada para nuestros propósitos. Se configura a través de los bits PS0, PS1 y PS2 del registro OPTION.

    La frecuencia Fosc/4 es una cuarta parte de la frecuencia de reloj. Utilizando un cristal de 4Mhz tendremos una Fosc/4 igual a 1 MHz, con lo que la cadencia de conteo que se obtiene provoca en TMR0 1 millón de incrementos por segundo (1/1.000.000 seg. =1MHz), que para muchas aplicaciones podría resultar demasiado elevada.

    Con el uso del PRESCALER podemos dividir la frecuencia Fosc/4 configurando oportunamente los bits PS0, PS1 y PS2 del registro OPTION según la siguiente tabla:

PS2 PS1 PS0 DIVISOR FRECUENCIA DE SALIDA PREESCALER (Hz.)
0
0
0
2
500.000
0
0
1
4
250.000
0
1
0
8
125.000
0
1
1
16
62.500
1
0
0
32
31.250
1
0
1
64
15.625
1
1
0
128
7.812,5
1
1
1
256
3.906,25

    Ejemplo práctico:Introducir un retardo igual a un segundo utilizando el registro TMR0.

    Debemos programar el bit T0CS a 0 para seleccionar como fuente de conteo el reloj del PIC, el bit PSA también debe estar a 0 para asignar el PRESCALER al registro TMR0 en lugar de al Watch Dog Timer y los bits de configuración del PRESCALER a 100 para obtener una frecuencia de división igual a 1:32. La frecuencia que obtendremos en TMR0 será igual a:

    Fosc = 1Mhz / 32 = 31.250 Hz

    Memorizamos en TMR0 el valor 6 de modo que el registro TMR0 alcanza el cero después de 250 cuentas (256 - 6 = 250) obteniendo así una frecuencia de paso por cero del TMR0 igual a:

    31.250 / 250 = 125 Hz

    El siguiente paso será memorizar en un registro de 8 bits el valor 125 de tal modo que, decrementando este registro en 1 por cada paso por cero de TMR0, se obtenga una frecuencia de pasos por cero del registro igual a:

    125/125 = 1Hz (1 segundo).

    En resumen se trata de controlar si TMR0 ha alcanzado el valor cero, luego de reiniciarlo a 6 y decrementar el valor contenido en un registro con valor 125. Cuando el registro alcance también el valor cero, entonces habrá trascurrido un segundo.


DISPOSITIVOS LÓGICOS MICROPROGRAMABLES El PIC16F84A 5.17

Encapsulado y marcado del PIC16F84A

    El PIC16F84A puede presentarse en varios encapsulados:

    Marcado del encapsulado:

    Ejemplos:


Índice / Introducción Familia PIC18 Registros del PIC16F84A